Rolling-out Power-user by script

Modified on Tue, 25 Nov at 5:17 PM

TABLE OF CONTENTS

Installing in C:\Users\%USERNAME%\AppData\Local (RECOMMENDED)
Installing in C:\Program Files (x86)
Additional options for installation by script

Power-user offers an .msi file (link here), allowing your IT admin to roll out licenses centrally to users within your organization. This option is best if you have many users, as it will save each user the need to install and activate the license on their own.

The below scripts will:

Download Power-user
Install it
Activate the license

Before anything, contact us so to let us know you will be packaging Power-user, as there is a quick security check we will perform under 24h before your license key can be used for deployment.

The below scripts are for CMD, but you can alternatively use PowerShell. Contact us if you need a PowerShell script instead.

Installing in C:\Users\%USERNAME%\AppData\Local (RECOMMENDED)

To install in C:\Users\%USERNAME%\AppData\Local, run the following code in a command line (e.g. CMD) in the user context.

Make sure you first replace "XXXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXX" with your actual Power-user license key in the EDITABLE SECTION.

REM /!\ This script needs to run in the USER context /!\

REM ---- EDITABLE SECTION ----------------------------------------------------------------

REM Define the parameters to activate the end-user license:

REM 1. License key that will be used during Power-user activation
SET license_key="XXXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXX"

REM 2. Email address that will be used during Power-user activation
REM Retrieving the email address of the end-user

REM Option 1: retrieve email address dynamically using whoami /upn
for /f "delims=" %%A in ('whoami /upn') do set email=%%A

REM Option 2: Define the email address manually or using another method
REM SET email=""

REM Option 3: leave the email variable empty, and the user will be registered with the Windows User Name
REM SET email=""

REM ---- END OF EDITABLE SECTION ---------------------------------------------------------

REM Make sure the license_key parameter is defined
IF %license_key% == "XXXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXX" (
	echo "Please define the license_key parameter"
	pause
	exit
)

IF %license_key% == "" (
	echo "Please define the license_key parameter"
	pause
	exit
)

REM Define variable that will be used to download Power-user
SET download_path=%temp%\Power-user.exe

REM Download the Power-user.exe file
bitsadmin /transfer "Download Power-user exe file" "https://powerusersoftware.com/download/Power-user.exe" "%download_path%"

REM Install Power-user
%download_path% /S /v/qn

REM Define variable that will be used to activate Power-user
SET install_path=C:\Users\%username%\AppData\Local

REM Activation of the end-user license providing the user name, license key and email address
"%install_path%\Power-user\PowerUserActivator.exe" %USERNAME% %license_key% %email%

After running this script, Power-user will be both installed and activated on the machine, without requiring the user to take any individual action.

Installing in C:\Program Files (x86)

Generally speaking, we recommend installing in C:\Users\%USERNAME%\AppData\Local using the script above, and not in C:\Program Files (x86). This is to allow users to keep their version up to date without needing an intervention from the IT admin.

In order to have full control over which version users are using, some admins can prefer to install in C:\Program Files (x86). In that case, users will not be able to get updates on their own and will require the script to be run again to install newer versions in the future.

To install in C:\Program Files (x86), run the script below:

Launch a command line (e.g. CMD) in the admin context, and run the following code:

REM /!\ This script needs to run in the ADMIN context /!\

REM ---- EDITABLE SECTION ----------------------------------------------------------------

REM Define the parameters to install Power-user
REM 1. Installation path
SET install_path=C:\Program Files (x86)

REM ---- END OF EDITABLE SECTION ---------------------------------------------------------

SET download_path="%temp%\Power-user.msi"
SET download_bat_path="%temp%\addin_registry.bat"

REM Download "Power-user.msi" file
bitsadmin /transfer "Download Power-user msi file" "https://powerusersoftware.com/download/Power-user.msi" %download_path%

REM Install Power-user
msiexec /i %download_path% ALLUSERS="2" INSTALLDIR="%install_path%" /q

REM Download the Power-user registry file
bitsadmin /transfer "Download Power-user addin_registry file" "https://powerusersoftware.com/Content/Installation/addin_registry.txt" %download_bat_path%

REM Tells office where Power-user is located
%download_bat_path%

Then, launch again the command line in the user context, and run the following code, after replacing XXXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXX with your license key in the EDITABLE SECTION.

REM /!\ This script needs to run in the USER context /!\

REM ---- EDITABLE SECTION ----------------------------------------------------------------

REM Define the parameters to activate the end-user license:

REM 1. License key that will be used during Power-user activation
SET license_key="XXXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXX"

REM 2. Email address that will be used during Power-user activation
REM Retrieving the email address of the end-user

REM Option 1: retrieve email address dynamically using whoami /upn
for /f "delims=" %%A in ('whoami /upn') do set email=%%A

REM Option 2: Define the email address manually or using another method
REM SET email=""

REM Option 3: leave the email variable empty, and the user will be registered with the Windows User Name
REM SET email=""

REM ---- END OF EDITABLE SECTION ---------------------------------------------------------

REM Make sure the license_key parameter is defined
IF %license_key% == "XXXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXX" (
	echo "Please define the license_key parameter"
	pause
	exit
)

IF %license_key% == "" (
	echo "Please define the license_key parameter"
	pause
	exit
)

REM Define variables that will be used to install and activate Power-user
SET install_path=C:\Program Files (x86)

REM Activation of the end-user license providing the user name, license key and email address
"%install_path%\Power-user\PowerUserActivator.exe" %USERNAME% %license_key% %email%

After running this script, Power-user will be installed and activated on the machine, without requiring the user to take any individual action.

Updates
When licenses are roll-out by script in C:\Program Files (x86), software updates will have to be handled by script as well.

Additional options for installation by script

Fixing email addresses

In the event that the command to get the user email address does not work in your environment, you can use Option 3 leaving the email parameter blank, and Power-user will default to using the Windows User Name concatenated with your organization's email domain.

If this is not the real email address, you can send us a list mapping the Windows user names with the real email addresses and we can update the data in your portal afterwards.

Installing the certificate

The first time Microsoft Office is restarted after the installation of Power-user, users might see a trust prompt. To avoid creating any confusion, this prompt can be avoided by installing the Power-user certificate in the Trusted Publisher store.

To do this by script, launch a command line (e.g. CMD) in the user context, and run the following code:

REM /!\ This script needs to run in the USER context /!\

SET download_path="%temp%\power_user_certificate.cer"

REM Download Power-user certificate
bitsadmin /transfer "Download Power-user certificate file" "https://powerusersoftware.com/download/power_user_certificate.cer" %download_path%

certutil.exe -addstore -user TrustedPublisher %download_path%

Plane mode

Certain organizations require their computers to be isolated from the Internet, due to the sensitive nature of their industry. We don't recommend this unless there is a strong necessity for it, but Power-user can be installed in plane mode by running the following command line in the admin context:

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Power-user" /v ContactServer /t REG_SZ /d "0" /f

If plane mode is turned on before activation, the activation cannot be performed through the server. We can still activate through an offline process. Feel free to contact us for more information about this.

When the license is in plane mode, it will notably have the following side-effects:

License management: when licenses are renewed, our server will not be able to remotely update the license validity. So each renewal will require the admin to momentarily turn off plane mode, activate the updated license key and turn plane mode on again.
Software updates will not be pushed to the users. The admin can still manually install them.
Features: the Pictures and Logo features will not be functional, as they require getting content from the web.

Hiding or disabling specific features

Certain features or items from the Power-user Library can be hidden from the users, if you don't want them to see or use them.

For this, run the chosen command lines below, in the admin context:

To hide the AI Assistant feature for rewording text

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Power-user" /v EnableSmartRewording /t REG_SZ /d "0" /f

To hide the AI feature for generating pictures

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Power-user" /v EnableLibraryPicturesAI /t REG_SZ /d "0" /f

To hide all libraries calling third-party resources (currently: Pexels, Unsplash, Clearbit, AI-generated pictures; AI Assistant):

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Power-user" /v EnableExternalLibraries /t REG_SZ /d "0" /f

To hide the Pictures menu entirely from the Library:

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Power-user" /v EnableLibraryPictures /t REG_SZ /d "0" /f

To hide the Tombstones menu from the Library:

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Power-user" /v EnableLibraryTombstones /t REG_SZ /d "0" /f